本节，我们将通过脉宽调制技术来实现“呼吸灯”，实现LED的亮度由最暗逐渐增加到最亮，再逐渐变暗的过程。 脉冲宽度调制(PWM:Pulse Width Modulation)，简称脉宽调制。它是利用微控制器的数字输出调制实现，是对模拟电路进行控制的一种非常有效的技术，广泛应用于测量、通信、功率控制与变换等众多领域。

呼吸灯的设计较为简单，我们使用12MHz的系统时钟作为高频信号做分频处理，调整占空比实现PWM，通过LED灯LD1指示输出状态。

实现原理如上图所示，脉冲信号的周期为T，高电平脉冲宽度为t，占空比为t/T。为了实现PWM脉宽调制，我们需要保持周期T不变，调整高电平脉宽t的时间，从而改变占空比。

• 当t = 0时，占空比为0%，因为我们的LED硬件为低电平点亮，所以为最亮的状态。
• 当t = T时，占空比为100%，LED灯为最暗（熄灭）的状态。

结合呼吸灯的原理，整个呼吸的周期为最亮→最暗→最亮的时间，即t的值的变化：0→T→0逐渐变化，这个时间应该为2s

呼吸灯设计要求呼吸的周期为2s，也就是说LED灯从最亮的状态开始，第一秒时间内逐渐变暗，第二秒的时间内再逐渐变亮，依次进行。

本设计中需要两个计数器cnt1和cnt2，cnt1随系统时钟同步计数（系统时钟上升沿时cnt1自加1）范围为0~T，cnt2随cnt1的周期同步计数（cnt1等于T时，cnt2自加1）范围也是0~T，这样每次cnt1在0~T的计数时，cnt2为一个固定值，相邻cnt1计数周期对应的cnt2的值逐渐增大，我们将cnt1计数0~T的时间作为脉冲周期，cnt2的值作为脉冲宽度，则占空比 = cnt2/T,占空比从0%到100%的时间 = cnt2*cnt1 = T^2 = 1s = 12M个系统时钟，T = 2400，我们定义CNT_NUM = 2400作为两个计数器的计数最大值。

module breath_led(clk_in,rst_n_in,Breath_led);
 
	input clk_in;
	input rst_n_in;
	output Breath_led;
 
	reg [24:0] cnt1;
	reg [24:0] cnt2;
	reg flag;
 
	parameter   CNT_NUM = 2400;	//period = (2400^2)*2 = 24000000 = 2s
	//generate cnt1 signal
	always@(posedge clk_in or negedge rst_n_in) begin 
		if(!rst_n_in) begin
			cnt1<=13'd0;
			end else begin
		if(cnt1>=CNT_NUM-1) cnt1<=1'b0;
			else cnt1<=cnt1+1'b1; end
		end
 
	//generate cnt2 signal
	always@(posedge clk_in or negedge rst_n_in) begin 
		if(!rst_n_in) begin
			cnt2<=13'd0;
			flag<=1'b0;
			end else begin
		if(cnt1==CNT_NUM-1) begin
			if(!flag) begin
				if(cnt2>=CNT_NUM-1) flag<=1'b1;
				else cnt2<=cnt2+1'b1;
			end else begin
				if(cnt2<=0) flag<=1'b0;
				else cnt2<=cnt2-1'b1;
			end
				end else cnt2<=cnt2;
			end
			end
 
	//Compare cnt1 and cnt2, generate PWM-Breath-led
	assign	Breath_led = (cnt1<cnt2)?1'b0:1'b1;
 
endmodule

引脚分配如下：

配置好以后编译下载程序，可以调整分频器的参数来调整流水灯的速度。

脉宽调制是一种值得广大工程师在许多应用设计中使用的有效技术，在下一小节我们会学习状态机的使用方法：交通灯的设计。