2021暑假一起练-用基于小脚丫FPGA的综合技能训练平台完成一个数字电压表

内容介绍

一、项目要求

利用ADC制作一个数字电压表

1.旋转电位计可以产生0-3.3V的电压

2.利用板上的串行ADC对电压进行转换

3.将电压值在板上的OLED屏幕上显示出来

二、设计思路

旋转电位计产生电压，由ADC电路对于产生的模拟电压进行数字化，然后通过bin_to_bcd模块将电压值转化为BCD编码；将BCD编码传至OLED模块并将其显示出来最后综合整理，完成顶层文件的编写。

FohI9fgcsKWbHohFfccW7dLMlwag

图2.1 制作数字电压表原理框图

如图2.1所示，整个数字电压表由一个顶层模块和四个功能模块组成。四个功能模块分别是串行ADC驱动模块，数值转换模块、OLED显示模块和数码管显示模块。由于要求制作数字电压表，而电压值是模拟量，所以我们需要使用ADC（模数转换器）把模拟信号转换为数字信号。本次使用的板卡带有ADS7868芯片，通过编写驱动程序，可以驱动该芯片对电位计电压值进行采样，得到8位的采样数据。之后通过SPI总线与数字FPGA进行通信。当然，采样获得的8位数据是一个相对量度值，范围是0~255，而实际的电压值范围是0~3.3V，所以进行一个乘法运算，256对应3.3V，0对应0V。接下来，我们希望将电压值显示在OLED 屏幕上和数码管上。由于采样数据是二进制表示的，所以显示之前，先要进行数值转换，从bin码转换为bcd码。

FhRXlf0LJea9b6cNihfefMYcp0qC

三、项目原理及代码展示

3.1 ADC模块实现

模数转换器即A/D转换器，或简称ADC，通常是指一个将模拟信号转变为数字信号的电子元件。通常的模数转换器是将一个输入电压信号转换为一个输出的数字信号。该模块负责完成ADC数据的采样，并将其传输给后面的模块，便于后面进行BCD码转换。该模块直接使用了电子森林里面的源代码。

module ADS7868
(
input				clk,		//系统时钟
input				rst_n,  	//系统复位，低有效

output	reg			adc_cs,		//SPI总线CS
output	reg			adc_clk,	//SPI总线SCK
input				adc_dat,	//SPI总线SDA

output	reg			adc_done,	//ADC采样完成标志
output	reg [7:0]	adc_data	//ADC采样数据
);

localparam	HIGH = 1'b1;
localparam	LOW  = 1'b0;

reg [7:0] cnt; //计数器
always @(posedge clk or negedge rst_n)
	if(!rst_n) cnt <= 1'b0;
	else if(cnt >= 8'd34) cnt <= 1'b0;
	else cnt <= cnt + 1'b1;
	
reg [7:0] data;
always @(posedge clk or negedge rst_n)
	if(!rst_n) begin
		adc_cs <= HIGH; adc_clk <= HIGH; 
		data <= 1'b0; adc_data <= 1'b0; adc_done <= LOW;
	end else case(cnt)
		8'd0 :  begin adc_cs <= HIGH; adc_clk <= HIGH; end
		8'd1 :  begin adc_cs <= LOW;  adc_clk <= HIGH; end
		8'd2,8'd4,8'd6,8'd8,8'd10,8'd12,8'd14,8'd16,
		8'd18,8'd20,8'd22,8'd24,8'd26,8'd28,8'd30,8'd32:	
				begin adc_cs <= LOW;  adc_clk <= LOW;  end
		8'd3 :  begin adc_cs <= LOW;  adc_clk <= HIGH; end 						//0
		8'd5 :  begin adc_cs <= LOW;  adc_clk <= HIGH; end 						//1
		8'd7 :  begin adc_cs <= LOW;  adc_clk <= HIGH; end 						//2
		8'd9 :  begin adc_cs <= LOW;  adc_clk <= HIGH; data[7] <= adc_dat; end 	//3
		8'd11 : begin adc_cs <= LOW;  adc_clk <= HIGH; data[6] <= adc_dat; end	//4
		8'd13 : begin adc_cs <= LOW;  adc_clk <= HIGH; data[5] <= adc_dat; end 	//5
		8'd15 : begin adc_cs <= LOW;  adc_clk <= HIGH; data[4] <= adc_dat; end 	//6
		8'd17 : begin adc_cs <= LOW;  adc_clk <= HIGH; data[3] <= adc_dat; end 	//7
		8'd19 : begin adc_cs <= LOW;  adc_clk <= HIGH; data[2] <= adc_dat; end 	//8
		8'd21 : begin adc_cs <= LOW;  adc_clk <= HIGH; data[1] <= adc_dat; end 	//9
		8'd23 : begin adc_cs <= LOW;  adc_clk <= HIGH; data[0] <= adc_dat; end 	//10
		8'd25 : begin adc_cs <= LOW;  adc_clk <= HIGH; adc_data <= data; end 	//11
		8'd27 : begin adc_cs <= LOW;  adc_clk <= HIGH; adc_done <= HIGH; end 	//12
		8'd29 : begin adc_cs <= LOW;  adc_clk <= HIGH; adc_done <= LOW; end 	//13
		8'd31 : begin adc_cs <= LOW;  adc_clk <= HIGH; end 						//14
		8'd33 : begin adc_cs <= LOW;  adc_clk <= HIGH; end 						//15
		8'd34 : begin adc_cs <= HIGH;  adc_clk <= HIGH; end
		default : begin adc_cs <= HIGH;  adc_clk <= HIGH;  end
	endcase

endmodule

3.2 数值转换模块（bin to bcd）

将二进制数转换成BCD码的形式，采用左移加三的算法。该模块是将前面ADC采样的数据转化为BCD编码，便于在OLED屏幕上进行实现，该模块也是使用电子森林已有的代码。

module bin_to_bcd					//此模块为了将ADC采样的数据转换为我们常用的十进制显示而存在
(
input						rst_n,	//系统复位，低有效
input		[15:0]			bin_code,	//需要进行BCD转码的二进制数据
output	reg	[19:0]			bcd_code	//转码后的BCD码型数据输出
);

reg		[35:0]		shift_reg; 

always@(bin_code or rst_n)begin
	shift_reg = {20'h0,bin_code};
	if(!rst_n) bcd_code = 0; 
	else begin 
		repeat(16) begin //循环16次  
			//BCD码各位数据作满5加3操作，
			if (shift_reg[19:16] >= 5) shift_reg[19:16] = shift_reg[19:16] + 2'b11;
			if (shift_reg[23:20] >= 5) shift_reg[23:20] = shift_reg[23:20] + 2'b11;
			if (shift_reg[27:24] >= 5) shift_reg[27:24] = shift_reg[27:24] + 2'b11;
			if (shift_reg[31:28] >= 5) shift_reg[31:28] = shift_reg[31:28] + 2'b11;
			if (shift_reg[35:32] >= 5) shift_reg[35:32] = shift_reg[35:32] + 2'b11;
			shift_reg = shift_reg << 1; 
		end
		bcd_code = shift_reg[35:16];   
	end  
end

endmodule

3.3 OLED模块（OLED12832）

OLED模块的实现主要是借鉴电子森林中的现有代码，只需要把需要显示的部分进行修改即可。这里主要展示main函数部分。

MAIN:begin
						if(cnt_main >= 5'd4) cnt_main <= 5'd2;
						else cnt_main <= cnt_main + 1'b1;
						case(cnt_main)	//MAIN状态
							5'd0:	begin state <= INIT; end
							5'd1:	begin y_p <= 8'hb0; x_ph <= 8'h10; x_pl <= 8'h00; num <= 5'd16; char <= "zhouhanqisdesign";state <= SCAN; end
							5'd2:	begin y_p <= 8'hb2; x_ph <= 8'h10; x_pl <= 8'h00; num <= 5'd16; char <=   {"        ",number1,8'd46,number2,number3,number4,8'd86,"  "};state <= SCAN; end
							5'd3:	begin y_p <= 8'hb1; x_ph <= 8'h10; x_pl <= 8'h00; num <= 5'd16; char <= "Voltage:        ";state <= SCAN; end
							5'd4:	begin y_p <= 8'hb3; x_ph <= 8'h10; x_pl <= 8'h00; num <= 5'd16; char <= "----------------";state <= SCAN; end
 
							default: state <= IDLE;
						endcase
					end

3.4 数码管显示模块（Seg led）

该模块用于在数码管上显示电压值。数码管只可显示两位数字。这部分的代码借鉴现有案例关于数码管显示的部分。

module Seg_led
(
input 		[3:0]	seg_data,	//seg_data input
input				seg_dot,	//segment dot control
output				seg_sel,	//segment com port
output reg	[7:0]	seg_led		//MSB~LSB = DP,G,F,E,D,C,B,A
);


always@(seg_data)
	case(seg_data)
		4'h0: seg_led = {seg_dot,7'h3f};  //  0
		4'h1: seg_led = {seg_dot,7'h06};  //  1
		4'h2: seg_led = {seg_dot,7'h5b};  //  2
		4'h3: seg_led = {seg_dot,7'h4f};  //  3
		4'h4: seg_led = {seg_dot,7'h66};  //  4
		4'h5: seg_led = {seg_dot,7'h6d};  //  5
		4'h6: seg_led = {seg_dot,7'h7d};  //  6
		4'h7: seg_led = {seg_dot,7'h07};  //  7
		4'h8: seg_led = {seg_dot,7'h7f};  //  8
		4'h9: seg_led = {seg_dot,7'h6f};  //  9
		4'ha: seg_led = {seg_dot,7'h77};  //  A
		4'hb: seg_led = {seg_dot,7'h7C};  //  b
		4'hc: seg_led = {seg_dot,7'h39};  //  C
		4'hd: seg_led = {seg_dot,7'h5e};  //  d
		4'he: seg_led = {seg_dot,7'h79};  //  E
		4'hf: seg_led = {seg_dot,7'h71};  //  F
		default: seg_led = {seg_dot,7'h00};
	endcase
assign seg_sel = 1'b0;

endmodule

3.5 顶层模块（Digital Voltmeter）

顶层模块需要把各个模块实例化，写明对应的输入输出量。中间在把ADC的采样数据传送到转码模块之前，按要求转化成电压值。

module Digital_Voltmeter
(
input				clk,		//系统时钟
input				rst_n,		//系统复位，低有效

input				adc_dat,	//SPI总线SDA
output				adc_cs,		//SPI总线CS
output				adc_clk,	//SPI总线SCK

output  			seg1_sel,	//数码管位选
output  	[7:0]	seg1_led,	//数码管段选
output  			seg2_sel,	//数码管位选
output  	[7:0]	seg2_led,	//数码管段选

output				oled_csn,	//OLCD液晶屏使能
output				oled_rst,	//OLCD液晶屏复位
output				oled_dcn,	//OLCD数据指令控制
output				oled_clk,	//OLCD时钟信号
output				oled_dat	//OLCD数据信号
);
wire adc_done;
wire [7:0] adc_data;
//ADC功能，例化

ADS7868 u2
(
.clk				(clk			),	//系统时钟
.rst_n				(rst_n			),	//系统复位，低有效
.adc_cs				(adc_cs			),	//SPI总线CS
.adc_clk			(adc_clk		),	//SPI总线SCK
.adc_dat			(adc_dat		),	//SPI总线SDA
.adc_done			(adc_done		),	//ADC采样完成标志
.adc_data			(adc_data		)	//ADC采样数据
);

//将ADC采样数据按规则转换为电压数据（乘以0.0129），这里我们直接乘以129，得到的数据经过BCD转码后小数点左移4位即可
wire [15:0]	bin_code = adc_data * 16'd129;
wire [19:0]	bcd_code;

//将处理后的ADC数据进行BCD转码，例化

bin_to_bcd u3
(
.rst_n				(rst_n			),	//系统复位，低有效
.bin_code			(bin_code		),	//需要进行BCD转码的二进制数据
.bcd_code			(bcd_code		)	//转码后的BCD码型数据输出
);

OLED12832 u4
(
.clk                (clk            ),		//12MHz系统时钟
.rst_n	            (rst_n			),	    //系统复位，低有效
	
.bcdcode	        (bcd_code[19:0]       ),
	
.oled_clk           (oled_clk       ),
.oled_csn           (oled_csn       ),
.oled_dat           (oled_dat       ),
.oled_dcn           (oled_dcn       ),
.oled_rst           (oled_rst       )
);

//Segment led display module
Seg_led seg[1:0] 
(
.seg_data			(bcd_code[19:12]	),	//seg_data input
.seg_dot			({1'b1,1'b0}		),	//segment dot control
.seg_sel			({seg1_sel,seg2_sel}),	//segment com port
.seg_led			({seg1_led,seg2_led})	//MSB~LSB = DP,G,F,E,D,C,B,A
); 

endmodule

实物结果展示

四、感悟与收获

通过这次小脚丫FPGA综合训练项目，我对于FPGA和verilog语言有了更深刻的认识，对于数字电路方面的知识也有了一个大致的回顾和思考。而且，这次训练还锻炼了我们的动手能力和自学能力，对今后自己的学习生活有很大的帮助，虽然现在只懂了FPGA的皮毛知识，但是相信自己以后会学的更加深入的。