本项目为硬禾学堂的2022寒假在家练ESP32-S2物联网平台的项目六，主要的要求为不使用板外资源硬件资源的情况下使用板载的OLED显示屏显示本地时间、温度和气象信息。该项目主要锻炼了物联网系统的开发思路以及大致流程。

      由于需要时间、温度和气象等数据，并且无法使用外部硬件资源，因此选择网络进行各种信息的获取。详细思路如下：

1、OLED驱动部分：

      由于本项目使用Arduino平台进行开发，因此可以调用丰富的显示驱动库，比如：`U8g2`、`adafruit`等等。本项目采用`U8g2`库进行OLED地驱动。

​       Arduino中提供了U8g2库的“傻瓜式”下载方式：

​       在工具中选择工具——选择“管理库”——在界面中搜索“U8g2”后下载安装即可。

#include <Arduino.h>
#include <HTTPClient.h>
#include <WiFI.h>
#include <SPI.h>
#include <WiFiMulti.h>
#include <U8g2lib.h>
#include <ArduinoJson.h>
#include <time.h>

int PIN_SCK = 36;//IO36
int PIN_SDA = 35;//IO35
int PIN_RST = 34;//IO34
int PIN_DC  = 33;//IO33
int PIN_CS  = 37;//IO37
int PIN_KEY1 = 1;//IO1
int PIN_KEY2 = 2;//IO2
int PIN_KEY3 = 3;//IO3
int PIN_KEY4 = 6;//IO6

const char* ssid     = "xxxx";////网络名称   
const char* password = "xxxx";//"2019210194";//网络密码   
const char *ntpServer = "cn.ntp.org.cn";//ntp服务器地址
const long gmtOffset_sec = 8*3600;
const int daylightOffset_sec =8*3600;//用于将时间校正到东八区
StaticJsonDocument<500> doc;		//存储IP定位的JSON数据
StaticJsonDocument<500> weatherDoc;	//存储天气的JSON数据
StaticJsonDocument<200> IPDoc;		//存储公网IP的JSON数据

struct tm timeinfo;		//存储当前时间

WiFiMulti wifiMulti;	//用于连接WiFi

U8G2_SSD1306_128X64_NONAME_1_4W_SW_SPI u8g2(U8G2_R0,PIN_SCK,PIN_SDA,PIN_CS,PIN_DC,PIN_RST);

int GetTime()
{
  if (!getLocalTime(&timeinfo))
  {
    Serial.println("Failed to obtain time");
    return 0;
  }
//  Serial.println(&timeinfo, "%A, %Y-%m-%d %H:%M:%S");
  return 1;
  
}

void getPublicIP()
{
  HTTPClient http;	//初始化HTTP对象
  
  Serial.println("[HTTP] begin...");
  String url = "https://api.myip.com/";	//获取公网IP的API
  http.begin(url); //HTTP
  Serial.println("[HTTP] GET...");
  int httpCode = http.GET();
  if(httpCode > 0)
  {
    Serial.print("[HTTP] GET... code: ");
    
    Serial.print(httpCode);

    if(httpCode == HTTP_CODE_OK)	//若访问成功，将数据装载到相应的StaticJsonDocument中
    {
      String payload = http.getString();
      deserializeJson(IPDoc, payload);
      
      Serial.println(payload);		//若访问失败，打印状态码
    }else
    {
      Serial.print("[HTTP] GET... failed, error: ");
      Serial.print(http.errorToString(httpCode).c_str());
    }
    http.end();
  }  
}

void GetIPPos()
{
  HTTPClient http;

  Serial.println("[HTTP] begin...");
  String url;
  String str1 = "https://apis.map.qq.com/ws/location/v1/ip?ip=";
  String strIP = IPDoc["ip"];
  String str2 = "&key=xxxx";//IP定位API，为保护隐私，已抹去密钥
  url=str1 + strIP + str2;

  http.begin(url); 
  Serial.println("[HTTP] GET...");
  int httpCode = http.GET();
  if(httpCode > 0)
  {
    Serial.print("[HTTP] GET... code: ");
    Serial.print(httpCode);

    if(httpCode == HTTP_CODE_OK)
    {
      String payload = http.getString();
      deserializeJson(doc, payload);
      Serial.println(payload);
    }else
    {
      Serial.print("[HTTP] GET... failed, error: ");
      Serial.print(http.errorToString(httpCode).c_str());
    }
    http.end();
  }
}

void GetWeather()
{
  HTTPClient http;

  Serial.println("[HTTP] begin...");
  String url;
  String str1 = "https://api.seniverse.com/v3/weather/now.json?key=xxxx&location=";
  String str2 = "&language=zh-Hans&unit=c";
  String strCity = doc["result"]["ad_info"]["city"];	//天气查询API，为保护隐私，已抹去密钥
  url=str1 + strCity + str2;
  http.begin(url); //HTTP
  Serial.println("[HTTP] GET...");
  int httpCode = http.GET();
  if(httpCode > 0)
  {
    Serial.print("[HTTP] GET... code: ");
    
    Serial.print(httpCode);

    if(httpCode == HTTP_CODE_OK)
    {
      String payload = http.getString();
      deserializeJson(weatherDoc, payload);
      
      Serial.println(payload);
    }else
    {
      Serial.print("[HTTP] GET... failed, error: ");
      Serial.print(http.errorToString(httpCode).c_str());
    }
    http.end();
  }
}

void setup() {
  // put your setup code here, to run once:
  u8g2.begin();//初始化oled驱动
  u8g2.enableUTF8Print();
  Serial.begin(115200);//初始化串口，波特率为115200
  pinMode(PIN_KEY1,INPUT);
  pinMode(PIN_KEY2,INPUT);
  pinMode(PIN_KEY3,INPUT);//配置三个按钮为输入
  Serial.println("UART Initialized");

  wifiMulti.addAP(ssid, password);
  while(wifiMulti.run()!=WL_CONNECTED)	//尝试连接WiFi
  {
    delay(500);
    Serial.println(".");
  }
  Serial.println("WiFi connected!");
  Serial.print("IP:");
  Serial.println(WiFi.localIP());

  configTime(gmtOffset_sec, daylightOffset_sec, ntpServer);		//连接ntp服务器，同步时间
  
  GetTime();
  
  if(wifiMulti.run()==WL_CONNECTED)		//初次执行完整流程
  {
    getPublicIP();
    GetIPPos();
    GetWeather();
  }
}

void loop() {
  // put your main code here, to run repeatedly:
  String PublicIP = IPDoc["ip"];
  u8g2.firstPage();
  do//显示数据
  {
      GetTime();
      String resPos = doc["result"]["ad_info"]["city"];
      String resWeather = weatherDoc["results"][0]["now"]["text"];
      String resTemp = weatherDoc["results"][0]["now"]["temperature"];
      u8g2.setFont(u8g2_font_wqy14_t_gb2312);	//设置字库，字号为14
//      u8g2.drawStr(0,15,"Hello World");
      u8g2.setCursor(0,15);u8g2.print(&timeinfo,"%Y/%m/%d %H:%M:%S");//规定显示格式
      u8g2.setCursor(0,40);u8g2.print(resPos);//位置
      u8g2.setCursor(0,60);u8g2.print("天气:");
      u8g2.setCursor(40,60);u8g2.print(resWeather);//天气
      u8g2.setCursor(80,60);u8g2.print(resTemp);//温度
      u8g2.setCursor(95,60);u8g2.print("℃");
      
  }while(u8g2.nextPage());
  int buttonState = digitalRead(PIN_KEY1);
  int buttonState2 = digitalRead(PIN_KEY2);
  int buttonState3 = digitalRead(PIN_KEY3);//读取三个按钮的状态
  if(buttonState == LOW)//按键1：更新天气
  {
    GetWeather();
    Serial.println("updating weather...");
    delay(50);
  }
  if(buttonState2 == LOW)//按键2：打印IP信息
  {
    Serial.print("IP:");
    Serial.println(WiFi.localIP());
    Serial.print("PublicIP:");
    Serial.println(PublicIP);
    delay(50);
  }
  if(buttonState3 == LOW)//按键3：更新时间
  {
    Serial.println("Getting Time...");
    GetTime();
    delay(50);
  }
}